
//************ Here are all of the base spawners for various pickups ***********

//==============================================================================
//=============================== CLASS CHECKERS ===============================
//==============================================================================

// The main point of these is to see which character 
// is selected and spawn the appropriate item

ACTOR BackPackChecker : BackpackItem replaces BagOfHolding
{
	States
	{
		Spawn:
			TNT1 A 0 NoDelay A_JumpIf(CheckClass("Corvette",AAPTR_PLAYER1),"Whoops")
			TNT1 A 0 A_SpawnItemEx("BackpackSpawner")
			TNT1 A 0 A_Remove(0)
			Stop
		Whoops:
			TNT1 A 0 A_SpawnItemEx("ClassicBackpackSpawner")
			TNT1 A 0 A_Remove(0)
			Stop
	}
}

ACTOR BottleChecker : CustomInventory replaces ArtiTimeBomb
{	
	
	States
	{
		Spawn:
			TNT1 A 0 NoDelay A_JumpIf(CheckClass("Corvette",AAPTR_PLAYER1),"Whoops")
			TNT1 A 0 
			{
				If (GetCVAR("WildBottles") == 0)
				{
					A_SpawnItemEx("BottleSpawner");
				}
				If (GetCVAR("WildBottles") == 1)
				{
					A_SpawnItemEx("BrutalGreenSpawner");
				}
				If (GetCVAR("WildBottles") == 2)
				{
					A_SpawnItemEx("BrutalRedSpawner");
				}
				If (GetCVAR("WildBottles") == 3)
				{
					A_SpawnItemEx("BrutalBlueSpawner");
				}
				If (GetCVAR("WildBottles") == 4)
				{
					A_SpawnItemEx("BrutalGRSpawner");
				}
				If (GetCVAR("WildBottles") == 5)
				{
					A_SpawnItemEx("BrutalGBSpawner");
				}
				If (GetCVAR("WildBottles") == 6)
				{
					A_SpawnItemEx("BrutalRBSpawner");
				}
			}	
			Stop
		Whoops:
			TNT1 A 0 
			{
				If (GetCVAR("WildBottles") == 0)
				{
					A_SpawnItemEx("CBottleSpawner");
				}
				If (GetCVAR("WildBottles") == 1)
				{
					A_SpawnItemEx("ClassicGreenSpawner");
				}
				If (GetCVAR("WildBottles") == 2)
				{
					A_SpawnItemEx("ClassicRedSpawner");
				}
				If (GetCVAR("WildBottles") == 3)
				{
					A_SpawnItemEx("ClassicBlueSpawner");
				}
				If (GetCVAR("WildBottles") == 4)
				{
					A_SpawnItemEx("ClassicGRSpawner");
				}
				If (GetCVAR("WildBottles") == 5)
				{
					A_SpawnItemEx("ClassicGBSpawner");
				}
				If (GetCVAR("WildBottles") == 6)
				{
					A_SpawnItemEx("ClassicRBSpawner");
				}
			}	
			Stop
	}
}

ACTOR BottleChecker2 : BottleChecker replaces ArtiPoisonBag
{
}


//==============================================================================
//============================== PICKUP SPANWERS ===============================
//==============================================================================


ACTOR HDHealthBonus : Health
{
	+FLOATBOB
	+INVENTORY.ALWAYSPICKUP
	Inventory.Amount 1
	Inventory.MaxAmount 999
	Inventory.PickupSound "ARTIUP"
	Inventory.PickupMessage "$TXT_ITEMEXTRAHEALTH"
	
	States
	{
		Spawn:
			MRP2 A 1 Bright A_SpawnItemEx("RedPotionFlare",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
	}
}

ACTOR HDArmorBonus : ArmorBonus
{
	+FLOATBOB
	Armor.SavePercent 33.335
	Armor.SaveAmount 3
	Armor.MaxSaveAmount 999//200
	Scale 1.0
	Inventory.Icon "HUDHELM"
	Inventory.PickupSound "ARTIUP"
	Inventory.PickupMessage "$TXT_ITEMEXTRAARMOR"
	
	States
	{
		Spawn:
			ABNS A 1 Bright A_SpawnItemEx("BlueArmorFlare",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
	}
}

ACTOR HealthBonusSpawner : CustomInventory
{
	-COUNTITEM
	+FLOATBOB
	-INVENTORY.INVBAR
	+VULNERABLE
	+CANNOTPUSH
	+DONTSPLASH
	DamageFactor "Firemace", 0
	DamageFactor "Phoenix", 0
	DamageFactor "Bomb", 0
	DamageFactor "Pod", 0
	DamageFactor "Fire", 0
	DamageFactor "Kick",0
	Mass 100
	Inventory.PickupSound "ARTIUP"
	Inventory.PickupMessage "$TXT_ITEMEXTRAHEALTH"
	
	States
	{
		Spawn:
			MRP2 A 1 Bright A_SpawnItemEx("RedPotionFlare",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
		Pickup:
			TNT1 A 0 A_GiveInventory ("HDHealthBonus", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (10 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR ArmorBonusSpawner : CustomInventory
{
	-COUNTITEM
	+FLOATBOB
	-INVENTORY.INVBAR
	+VULNERABLE
	+CANNOTPUSH
	+DONTSPLASH
	DamageFactor "Firemace", 0
	DamageFactor "Phoenix", 0
	DamageFactor "Bomb", 0
	DamageFactor "Pod", 0
	DamageFactor "Fire", 0
	DamageFactor "Kick",0
	Mass 100
	Inventory.PickupSound "ARTIUP"
	Inventory.PickupMessage "$TXT_ITEMEXTRAARMOR"
	
	States
	{
		Spawn:
			ABNS A 1 Bright A_SpawnItemEx("BlueArmorFlare",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
		Pickup:
			TNT1 A 0 A_GiveInventory ("HDArmorBonus", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (10 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR BrutalCrystalVial : Health
{
	+FLOATBOB
	+DONTSPLASH
	Inventory.PickupSound "ARTIUP"
	Inventory.Amount 10
	Inventory.PickupMessage "That magic draught sure hit the spot!"
	
	States
	{
		Spawn:
			PTN1 AAABBBCCC 1 Bright A_SpawnItemEx("BluePotionFX1",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
	}
}

ACTOR BrutalMapScroll : MapRevealer
{
	+COUNTITEM
	+FLOATBOB
	+DONTSPLASH
	Inventory.PickupSound "ARTIUP"
	Inventory.MaxAmount 0
	Inventory.PickupMessage "With this map, you'll never get lost again... for this area anyway!"
	
	States
	{
		Spawn:
			SPMP A 1 Bright A_SpawnItemEx("InvuFlare4",0,0,32,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
	}
}

ACTOR HDMysticEnchantment : CustomInventory replaces Megasphere
{
	+COUNTITEM
	+FLOATBOB
	+DONTSPLASH
	+INVENTORY.PICKUPFLASH
	+INVENTORY.FANCYPICKUPSOUND
	+INVENTORY.ALWAYSPICKUP
	Scale 0.5
	Inventory.PickupSound "WPNUPL"
	Inventory.PickupMessage "Magical energies course through your veins!"
	
	States
	{
		Spawn:
			FACE ABCDEFGH 5 Bright
			Loop
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_DropItem ("BrutalEnchantedShield");
					A_GiveInventory ("GoldWandCharge", 100);
					A_GiveInventory ("BrutalCrossbowAmmo", 50);
					A_GiveInventory ("BrutalBlasterCharge", 200);
					A_GiveInventory ("SidheWrathCharge", 200);
					A_GiveInventory ("PhoenixRodCharge", 150);
					A_GiveInventory ("MaceCharge", 150);
					A_GiveInventory ("SkullRodCharge", 120);
					A_GiveInventory (Health,999);
					A_GiveInventory ("Mana",999);
					A_GiveInventory ("KraterCharge",25);
					A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")));

				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalEnchantedShield",6);
					A_GiveInventory ("BrutalSilverShield",6);
					A_GiveInventory (Health,999);
					A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")));
					A_DropItem ("BrutalSilverShield");
					A_DropItem ("BrutalEnchantedShield");

				}
			}
			stop
	}
}


//==============================================================================
//============================== ARTIFACT SPAWNERS =============================
//==============================================================================


ACTOR HealthSpawner : CustomInventory
{
	+FLOATBOB
	+INVENTORY.PICKUPFLASH
	+INVENTORY.FANCYPICKUPSOUND
	-INVENTORY.INVBAR
	+DONTSPLASH
	Inventory.PickupSound "misc/p_pkup"
	Inventory.PickupMessage "Picked up a Quartz Flask, for some healing on the go!"
	
	States
	{
		Spawn:
			PTN2 AAAABBBBCCCC 1 Bright A_SpawnItemEx("PurplePotionFX1",0,0,26,0,0,0,0,SXF_NOCHECKPOSITION)
			goto Spawn
		Pickup:
			TNT1 A 0 A_GiveInventory("BrutalArtiHealth",1)
			TNT1 A 0 A_GiveInventory("Experience", (5 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR SuperHealthSpawner : CustomInventory
{
	+FLOATBOB
	+INVENTORY.PICKUPFLASH
	+INVENTORY.FANCYPICKUPSOUND
	-INVENTORY.INVBAR
	+DONTSPLASH
	Inventory.PickupSound "misc/p_pkup"
	Inventory.PickupMessage "Picked up a Mystic Urn, wonder whose ashes are inside..."
	Inventory.InterHubAmount 16
	
	States
	{
		Spawn:
			SPHL A 1 Bright A_SpawnItemEx("PurplePotionFX1",0,0,26,0,0,0,0,SXF_NOCHECKPOSITION)
			goto Spawn
		Pickup:
			TNT1 A 0 A_GiveInventory("BrutalArtiSuperHealth",1)
			TNT1 A 0 A_GiveInventory("Experience", (10 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR TeleportSpawner : CustomInventory
{
	-INVENTORY.INVBAR
	+DONTSPLASH
	Inventory.PickupSound "PICUP5"
	Inventory.PickupMessage "Picked up a Chaos Device, There's no place like home..."
	
	States
	{
		Spawn:
			ATLP AAABBBCCCBBB 1 Bright A_SpawnItemEx("TeleDeviceFlare",0,0,29,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop	
		Pickup:
			TNT1 A 0 A_GiveInventory ("BrutalArtiTeleport", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR WingSpawner : CustomInventory replaces ArtiFly
{
	-INVENTORY.INVBAR
	+DONTSPLASH
	Inventory.PickupSound "PICUP5"
	Inventory.PickupMessage "Got the Wings of Wrath, be one with the wind!"
	
	States
	{
		Spawn:
			SOAR AAAABBBBCCCCBBBB 1 Bright A_SpawnItemEx("WingsOfWrathFlare",0,0,26,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
		Pickup:
			TNT1 A 0 A_GiveInventory ("BrutalArtiFly", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR ShadowSpawner : CustomInventory
{
	-INVENTORY.INVBAR
	+DONTSPLASH
	Inventory.PickupSound "PICUP5"
	Inventory.PickupMessage "Picked up a ShadowSphere, time to hide in plain sight!"
	
	States
	{
		Spawn:
			INVS A 1 Bright
			Loop
		Pickup:
			TNT1 A 0 A_GiveInventory ("BrutalShadowSphere", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR AdrenalineSpawner : CustomInventory
{
	+FLOATBOB
	-INVENTORY.INVBAR
	+DONTSPLASH
	Inventory.PickupSound "PICUP5"
	Inventory.PickupMessage "Got an Adrenaline Boost, In case Hell isn't exciting enough!"
	
	States
	{
		Spawn:
			TFUL A 1 Bright
			Loop
		Pickup:
			TNT1 A 0 A_GiveInventory ("AdrenalineBooster", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")))
			stop
	}
}

ACTOR EggSpawner : RandomSpawner
{
	+FLOATBOB
	DropItem "ChickenSpawner" 255,3
	DropItem "RoosterSpawner" 255,1
}

ACTOR ChickenSpawner : CustomInventory
{
	+FLOATBOB
	+DONTSPLASH
	-INVENTORY.INVBAR
	Inventory.Icon "ARTIEGGC"
	Inventory.PickupSound "misc/p_pkup"
	Inventory.PickupMessage "Picked up the Morph Ovum.	For when you want to devour your enemy."
	
	States
	{
		Spawn:
			EGGC AABBCCBB 1 Bright A_SpawnItemEx("EtherealFlare1",0,0,30,0,0,0,0,SXF_NOCHECKPOSITION)
			Loop
		Pickup:
			TNT1 A 0 A_GiveInventory ("BrutalChickenDevice", 1)
			TNT1 A 0 A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")))
			stop
	}
}


//==============================================================================
//=============================== WEAPON SPAWNERS ==============================
//==============================================================================


ACTOR GauntletsSpawner : CustomInventory
{
	Inventory.Pickupsound "WPNUPL"
	Inventory.PickupMessage "Gauntlets Aquired, time to fry some hellspawn!"
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("GreenFlareSmall",0,0,18)
			WGNT AA 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalGauntlets");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("FlechetteTosser");
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicGauntlets");
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
				}
			}	
			stop
	}
}

ACTOR CrossbowSpawner : CustomInventory
{
	+VULNERABLE
	+CANNOTPUSH
	DamageFactor "Firemace", 0
	DamageFactor "Phoenix", 0
	DamageFactor "Bomb", 0
	DamageFactor "Pod", 0
	DamageFactor "Fire", 0
	DamageFactor "Kick",0
	Mass 100
	+FLOAT
	Inventory.Pickupsound "WPNUP"
	Inventory.PickupMessage "Picked up the Ethereal Crossbow, a Heretic's best friend."
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("GreenFlareSmall",0,0,10)
			WBOW A 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalCrossbow");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("Experience", (10 * GetCvar("ExpModifier")));
					ACS_NamedExecute("GreenTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicCrossbow");
					A_GiveInventory ("Experience", (10 * GetCvar("ExpModifier")));
				}
			}
			Stop
	}
}

ACTOR DragonClawSpawner : CustomInventory
{
	+VULNERABLE
	+CANNOTPUSH
	+DONTSPLASH
	DamageFactor "Firemace", 0
	DamageFactor "Phoenix", 0
	DamageFactor "Bomb", 0
	DamageFactor "Pod", 0
	DamageFactor "Fire", 0
	DamageFactor "Kick",0
	Mass 100
	+FLOAT
	Inventory.Pickupsound "WPNUP"
	Inventory.PickupMessage "Picked up the Dragon Claw, time to RIP AND TEAR (but with magic!)"
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("BlueFlareSmall",0,0,10)
			WBLS AA 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalDragonClaw");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("BrutalBlasterAmmo",20);
					A_GiveInventory ("Experience", (10 * GetCvar("ExpModifier")));
					ACS_NamedExecute("BlueTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicDragonClaw");
					A_GiveInventory ("ClassicBlasterAmmo",20);
					A_GiveInventory ("Experience", (10 * GetCvar("ExpModifier")));
				}
			}
			stop
	}
}

ACTOR HellstaffSpawner : CustomInventory
{
	Inventory.Pickupsound "WPNUPL"
	Inventory.PickupMessage "Picked up the Hellstaff, engulf everything in radiant plasma!"
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("RedFlareSmall",0,0,20)
			WSKL XX 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalHellStaff");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("BrutalSkullRodAmmo",50);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
					ACS_NamedExecute("RedTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicHellStaff");
					A_GiveInventory ("ClassicSkullRodAmmo",50);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
				}
			}
			stop
	}
}

ACTOR PhoenixRodSpawner : CustomInventory
{
	Inventory.Pickupsound "WPNUPL"
	Inventory.PickupMessage "Picked up the Phoenix Rod, purify them with fire, that they may be reborn!"
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("YellowFlareSmall",0,0,20)
			WPHX AA 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalPhoenixRod");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("BrutalPhoenixRodAmmo",10);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
					ACS_NamedExecute("YellowTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicPhoenixRod");
					A_GiveInventory ("ClassicPhoenixRodAmmo",10);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
				}
			}
			stop
	}
}

ACTOR PhoenixRodSpawner2 : PhoenixRodSpawner
{
	Inventory.Pickupsound "WPNUPL"
	Inventory.PickupMessage "Picked up the Phoenix Rod, As well as the Sidhe's Wrath!"
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("YellowFlareSmall",0,0,20)
			WPHX AA 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalPhoenixRod");
					A_GiveInventory ("SidheWrath");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("BrutalPhoenixRodAmmo",10);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
					ACS_NamedExecute("YellowTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicPhoenixRod");
					A_GiveInventory ("ClassicSidheWrath");
					A_GiveInventory ("ClassicPhoenixRodAmmo",10);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
				}
			}
			stop
	}
}

ACTOR FireMaceSpawner : CustomInventory
{
	Inventory.Pickupsound "WPNUPL"
	Inventory.PickupMessage "Picked up the Fire Mace, unleash its wrath on your enemies!"
	
	States
	{
		Spawn:
			TNT1 A 0 A_SpawnItemEx("RedFlareSmall",0,0,20)
			WMCE AA 1 Bright A_SetAngle(angle+speed)
			Goto Spawn
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("BrutalFireMace");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("BrutalMaceAmmo",20);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
					ACS_NamedExecute("OrangeTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicFireMace");
					A_GiveInventory ("ClassicMaceAmmo",20);
					A_GiveInventory ("Experience", (50 * GetCvar("ExpModifier")));
				}
			}
			stop
	}
}

ACTOR SidheWrathSpawner : CustomInventory
{
	Inventory.Pickupsound "WPNUPL"
	Inventory.PickupMessage "The Sidhe's Wrath will assure your vengence"
	
	States
	{
		Spawn:
			SLSP A 1 Bright A_SetAngle(angle+speed)
			TNT1 A 0 A_SpawnItemEx("SidheWrathFlare",0,0,20)
			Loop
		Pickup:
			TNT1 A 0 
			{
				If (CheckClass("BrutalCorvus",AAPTR_PLAYER1) || CheckClass("CluckyPlayer",AAPTR_PLAYER1))
				{
					A_GiveInventory ("SidheWrath");
					A_GiveInventory ("Mana", (1 * GetCvar("ManaModifier")));
					A_GiveInventory ("BrutalPhoenixRodAmmo",100);
					A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")));
					ACS_NamedExecute("YellowTrap");
				}
				Else If (CheckClass("Corvette",AAPTR_PLAYER1))
				{
					A_GiveInventory ("ClassicSidheWrath");
					A_GiveInventory ("ClassicPhoenixRodAmmo",100);
					A_GiveInventory ("Experience", (100 * GetCvar("ExpModifier")));
				}
			}
			stop
	}
}


ACTOR BrutalExplosivePod : Pod
{
	Health 30
	Radius 16
	Height 54
	//Mass 50
	//+NOPAIN
	-DONTGIB
	-OLDRADIUSDMG
	+NOBLOOD
	-NOBLOCKMONST
	+NODAMAGETHRUST
	+DONTGIB
	+ALLOWPAIN
	+SLIDESONWALLS
	DamageFactor "Pod", 0.7
	DamageFactor "FlameyBoi", 0
	DamageFactor "Kick", 0
	DamageFactor "GoldWand", 30
	DamageType "Pod"
	DeathSound ""
	Painchance 256
	Painchance "FlameyBoi", 0
	PushFactor 0.5//.01

	States
	{
		Spawn:
			PPOD A 10
			Loop
		Pain.Kick:
			TNT1 A 0 A_Stop
			PPOD A 1 A_FaceTarget
			TNT1 A 0 ThrustThingZ(0,45,0,1)
			TNT1 A 0 A_Recoil(35)
			Goto Spawn
		Death:
			TNT1 A 0 A_ChangeFlag(PUSHABLE,FALSE)
			//TNT1 A 0 A_Stop
			TNT1 A 0 A_NoBlocking
			PPOD A 2 A_RemovePod
			TNT1 A 0 A_PlaySound("DSBAREXP",1)
			PPOD B 4 Light("GREENKNIGHTAXE_EX1")
			PPOD C 4 Light("GREENKNIGHTAXE_EX2")
			//TNT1 A 0 Radius_Quake(2,14,0,12,0)
			TNT1 A 0 A_QuakeEx (2,2,2,16,0,600,"world/quake",QF_SCALEDOWN,0,0,0,230)
			TNT1 AAA 0 A_CustomMissile("PlasmaSmoke",0,0,random(1,360),2,random(1,360))
			TNT1 A 0 A_SpawnItemEx("GreenExplosionFire",0,0,43,0,0,0,0,SXF_NOCHECKPOSITION)
			TNT1 AAAAAAAAAAAAAAAA 0 A_CustomMissile ("GreenExplosionParticle1", 43, 0, random (0, 360), 2, random (0, 360))
			TNT1 A 0 A_Explode(140,230,XF_HURTSOURCE,TRUE,0,0,0,"DummyPuff","Pod")
			PPOD D 4 Light("GREENKNIGHTAXE_EX3")
			PPOD E 4 Light("GREENKNIGHTAXE_EX4")
			PPOD F 4 Light("GREENKNIGHTAXE_EX5")
			TNT1 A 2 Light("GREENKNIGHTAXE_EX6")
			TNT1 A 2 Light("GREENKNIGHTAXE_EX7")
			Stop
		Grow:
			PPOD IJKLMNOP 3
			Goto Spawn
	}
}

ACTOR HDPodGen : PodGenerator replaces PodGenerator
{
	States
	{
		Spawn:
		TNT1 A 35 A_MakePod("BrutalExplosivePod")
		Loop
	}
}

ACTOR PodProjectile : BrutalExplosivePod
{
	+NOGRAVITY
	
	States
	{
		Spawn:
			PPOL IJKLMNOP 3
		Waiting:
			PPOL A 10
			Loop
	}
}

ACTOR PodProjectile2 : PodProjectile
{
	Mass 500
	-NOGRAVITY
}