//==SUPER SHOTGUN==
//Blaz gets a cleave effect for his powered sword
//attacks

//Doomslayer gets the Thunderbuss, a portable, powerful cannon
//that blasts foes with electrical shot

//Kustam gets a speed clip loader for reloading his
//weapon faster


Actor GMOTASSG : custominventory replaces supershotgun
{
	Radius 14
	Height 14
    +DONTGIB
	+quiet
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 1
        TNT1 A 0 A_CustomMissile ("BlazCleaveSprite",0,0,0,CMF_AIMDIRECTION)
        TNT1 A 0 A_CustomMissile ("DoomslayerSSGSprite",0,0,0,CMF_AIMDIRECTION)
        TNT1 A 0 A_CustomMissile ("KustamScatterComboSprite",0,0,0,CMF_AIMDIRECTION)
	spawn1:
		ITRO ABCDEFGH 1 Bright
		loop
	Pickup:
		TNT1 A 0
		TNT1 A 0 A_JumpIfInventory ("IamLordBlaz",1,"BlazCleave")
		TNT1 A 0 A_JumpIfInventory ("IamDoomSlayer",1,"DoomSlayerSSG")
		TNT1 A 0 A_JumpIfInventory ("IamKustam",1,"KustamScatterCombo")
		TNT1 A 1
		stop
	BlazCleave:
		TNT1 A 0
		TNT1 A 0
		TNT1 A 0 A_SetBlend (FFFF00,0.1,5)
		TNT1 A 0 A_PlaySound ("powerups/upgrade",CHAN_ITEM)
		TNT1 A 0 ACS_NamedExecuteAlways("WeaponLog",0,2,0,0)			
		TNT1 A 0 A_GiveInventory ("SwordCleaveUpgrade", 1)
		TNT1 A 1 A_GiveInventory ("arcaneforce", 30)
		TNT1 A 0 A_GiveInventory ("DecayPause",1)
		stop
	DoomslayerSSG:
		TNT1 A 0
		TNT1 A 0 ACS_NamedExecuteAlways("WeaponLog",0,2,0,0)			
		//TNT1 A 0 a_log ("You got the Thunderbuss cannon!")
		TNT1 A 0 A_PlaySound ("misc/w_pkup",CHAN_ITEM)
		TNT1 A 0 A_SetBlend (FFFF00,0.1,5)
		TNT1 A 0 A_GiveInventory ("SlayerGrit",20)
		TNT1 A 0 A_GiveInventory ("ThunderBuss",1)
		TNT1 A 1
		stop
	KustamScatterCombo:
		TNT1 A 0
		TNT1 A 0 ACS_NamedExecuteAlways("WeaponLog",0,2,0,0)			
		TNT1 A 0 A_PlaySound ("Kustam/upgradeget",CHAN_ITEM)
		TNT1 A 0 A_SetBlend (FFFF00,0.1,5)
		TNT1 A 0 A_GiveInventory ("KustamKineticBattery",15)
		TNT1 A 0 A_GiveInventory ("ScatterComboUpgrade",1)
		TNT1 A 1
		stop
	}
}

//Blaz item token
actor SwordCleaveUpgrade : inventory
{inventory.maxamount 1}

//Kustam Item Token
actor ScatterComboUpgrade : inventory
{inventory.maxamount 1}



//item sprites
actor BlazCleaveSprite : GMOTAweaponsprite
{
    VisibleToPlayerClass LordBlaz
    States
    {
	spawn:
		TNT1 A 0
		ACHR A 1 bright
		TNT1 A 0 a_warp (AAPTR_TARGET,0,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
		TNT1 A 0 a_checkflag ("SPECIAL","spawn",AAPTR_TARGET)
		ACHR A 1 bright
		goto death
	Death:
		TNT1 A 0
		TNT1 A 1 
		stop
    }
}

actor DoomSlayerSSGSprite : GMOTAweaponsprite
{
    VisibleToPlayerClass DoomSlayer
    States
    {
	spawn:
		TNT1 A 0
		TBPU A 1 bright
		TNT1 A 0 a_warp (AAPTR_TARGET,0,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
		TNT1 A 0 a_checkflag ("SPECIAL","spawn",AAPTR_TARGET)
		TBPU A 1 bright
		goto death
	death:
		TNT1 A 1
		stop
	}
}

actor KustamScatterComboSprite : GMOTAweaponsprite
{
    VisibleToPlayerClass Kustam
    States
    {
	spawn:
		TNT1 A 0
		HCSC A 1 bright
		TNT1 A 0 a_warp (AAPTR_TARGET,0,0,0,0,WARPF_INTERPOLATE|WARPF_NOCHECKPOSITION)
		TNT1 A 0 a_checkflag ("SPECIAL","spawn",AAPTR_TARGET)
		HCSC A 1 bright
		goto death
	death:
		TNT1 A 1
		stop
	}
}

