ACTOR RoyalDuke : steelduke
{
	MONSTER
	+DONTOVERLAP
	PainChance 180
	translation "167:191=192:207", "42:47=207:207", "120:127=180:186"
	Height 56
	Radius 16
	Mass 250
	Speed 12
	SeeSound "SteelDukeSee"
	DeathSound "SteelDukeDeath"
	PainSound "SteelDukePain"
	ActiveSound "SteelDukeActive"
    bloodtype Dukebloodsplatter
	Obituary "%o was struck down by a Royal Duke"
	hitobituary "%o has been smote by a Royal Duke"
	dropitem "shotgun" 256
	dropitem "lilchest" 05
	states
	{
	Melee:
		CRMD E 7 A_FaceTarget
		CRMD F 4 
		CRMD G 4 A_CustomMeleeAttack(20,"mace/hit","mace/swing")
		CRMD I 4
		Goto See
	Missile:
		CRMD E 1 A_PlaySound ("SteelDukeAttackTalk", 0)
		CRMD E 4 A_FaceTarget
		TNT1 A 0 A_JumpIfInventory ("BlueBallsRecovery",1,2)
		TNT1 A 0 A_Jump (120, "BlueBalls")
		CRMD J 4 BRIGHT
		CRMD J 4
		CRMD J 4 BRIGHT
		CRMD F 1 A_PlaySound ("SteelDukeSwing")
		CRMD F 4 
		CRMD I 4 A_FaceTarget
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,-12)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,-6)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,0)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,6)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,12)
		TNT1 A 0 A_Jump (60, "extrashot")
		CRMD G 4 BRIGHT
		CRMD I 2
		CRMD F 4
		Goto See
	extrashot:
		CRMD J 2 BRIGHT
		CRMD F 1 A_PlaySound ("SteelDukeSwing")
		CRMD F 2 
		CRMD I 2 A_FaceTarget
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,-5)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,-3)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,0)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,3)
		TNT1 A 0 A_CustomMissile ("MaceShot",32,0,5)
		CRMD G 4 BRIGHT
		CRMD I 2
		CRMD F 4
		Goto See
	BlueBalls:
		CRMD J 4
		CRMD J 4 BRIGHT
		CRMD F 1 A_PlaySound ("SteelDukeSwing")
		CRMD F 4 
		CRMD I 4 A_FaceTarget
		TNT1 A 0 A_CustomMissile ("BlueMaceBall",32,0,Random(-6,9))
		TNT1 A 0 A_CustomMissile ("BlueMaceBall",32,0,Random(-6,9))
		TNT1 A 0 A_CustomMissile ("BlueMaceBall",32,0,0)
		TNT1 A 0 A_CustomMissile ("BlueMaceBall",32,0,Random(-6,9))
		TNT1 A 0 A_CustomMissile ("BlueMaceBall",32,0,Random(-6,9))
		TNT1 A 0 A_GiveInventory ("BlueBallsRecovery",1)
		CRMD G 4 BRIGHT
		CRMD I 2
		CRMD F 4
		Goto See
	Death:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("droppedMace", 0, 0, 32, 10, 0, 0, -90, 128)
		CRIM A 1 A_Scream
		CRIM A 1 A_NoBlocking
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 thrustthingz (0,30,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 4, 0, 0)		
		CRIM B 3 
		CRIM CD 6
		CRIM E 3
		CRIM FG 5
		CRIM H 1 A_Jump (80, "deadtalk")
		CRIM H 0 A_Jump (8, "DarkPortal")
		CRIM H -1
		Stop				
	DarkPortal:
		TNT1 A 0
		CRIM H random(50,180) 
		TNT1 A 0 A_PlaySound ("Darkportal/form",0)
		CRIM H 3 Thing_SetTranslation(0, 4242)
		HWRP ABCD 1
		TNT1 A 1 A_SpawnItemEx ("WeakPortal")
		stop		

	XDeath:
		TNT1 A 0
		CRIM I 0 A_PlaySound ("SteelDukeSplatter", 0)
		CRIM I 1 A_Scream
		TNT1 A 0 A_SpawnItemEx("droppedMace", 0, 0, 32, 10, 0, 0, -90, 128)
		TNT1 A 0 A_NoBlocking
		CRIM IJK 2 
		TNT1 A 0 A_SpawnItem ("bigdukebloodsplatter")
		TNT1 AAAAAAAA 0 A_SpawnItemEx ("dukebloodsplatter",0,0,24)       
		//TNT1 AAAAAAAA 0 A_SpawnItem ("dukebloodsplatter") 
		TNT1 AAA 0 A_SpawnItemEx("bonegib",0,0,0,random(-10,10),random(-10,10),10)
		ISKL AAAAAAA 0 A_SpawnItemEx("hipbonegib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 A_SpawnItemEx("ribbonegib",0,0,32,random(-10,10),random(-10,10),12)
		CRIM LMNOP 5
		CRIM Q 1 A_Jump (20, "gibtalk")
		CRIM Q 0 A_Jump (8, "GibbedDarkPortal")
		CRIM Q -1
		stop
	GibbedDarkPortal:
		TNT1 A 0
		CRIM Q random(50,180) 
		TNT1 A 0 A_PlaySound ("Darkportal/form",0)
		CRIM Q 3 Thing_SetTranslation(0, 4242)
		HWRP ABCD 1
		TNT1 A 1 A_SpawnItemEx ("WeakPortal")
		stop				
	}
}


ACTOR BlueMaceBall : MaceShot
{
	+ISMONSTER
	+SHOOTABLE
	-NOBLOCKMAP
	-NOBLOOD
	-DORMANT
	-INVULNERABLE
	Health 90
	Radius 20
	Height 20
	ProjectilePassHeight 40
	Speed 8
	scale 1.50
	Damage (15)
	Decal Scorch
	bloodtype GMOTAnoBlood
	translation "80:111=192:207", "128:159=192:207", "0:15=200:207"
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 ThrustThingZ (0,random(0,3),random(0,1),1)
		TNT1 A 0 A_ScaleVelocity (FRandom(0.65,0.95))
	flying:
		FX18 MN 4
		loop
	Death:
		TNT1 A 0
		TNT1 A 0 Thing_SetTranslation(0, 0)
		MWND EFGHI 3 Bright
		Stop
	}
}


Actor BlueBallsRecovery : Powerup
{
  Powerup.Duration -10
}


