actor magegunner : arachnotron replaces arachnotron
{
	Health 500 
	PainChance 128
	Speed 13
	Radius 40
	Height 56 
	Mass 400 
	+DONTHARMSPECIES
	MONSTER
 	Painchance "BarrelGrab", 0
	bloodtype Dukebloodsplatter
	seesound "magegunner/spot"
	painsound "magegunner/pain"
	deathsound "magegunner/die"
	activesound ""
	+floorclip
    Obituary "%o was overwhelmed by a Mage Gunner's assault."
	states
	{
	spawn:
		MAGN AB 10 A_Look
		loop
	see:
		MAGN AABBCCDD 2 A_Chase
		loop
	missile:
		TNT1 A 0 A_Jump (60, "chargeshot")
		MAGN E 8 A_FaceTarget
		MAGN F 4 bright A_CustomMissile ("magerifleshot")
		TNT1 A 0 A_CustomMissile ("magerifleshot",32,0,random(-4,11),2,random(-2,4))
		MAGN E 2
		MAGN E 8 A_FaceTarget
		MAGN F 4 bright A_CustomMissile ("magerifleshot")
		TNT1 A 0 A_CustomMissile ("magerifleshot",32,0,random(-7,14),2,random(-3,2))
		MAGN E 2
		MAGN E 8 A_FaceTarget
		MAGN F 4 bright A_CustomMissile ("magerifleshot")
		TNT1 A 0 A_CustomMissile ("magerifleshot",32,0,random(-2,13),2,random(-2,3))
		goto see
	chargeshot:
		MAGN E 0 A_PlaySound ("magegunner/charge",0)
		MAGN E 0 A_FaceTarget
		MAGN E 5 bright A_SpawnItemEx ("riflechargeup1",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 A_SpawnItemEx ("riflechargeup1",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 bright A_SpawnItemEx ("riflechargeup2",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 A_SpawnItemEx ("riflechargeup2",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 bright A_SpawnItemEx ("riflechargeup3",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 A_SpawnItemEx ("riflechargeup3",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 bright A_SpawnItemEx ("riflechargeup3",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 A_SpawnItemEx ("riflechargeup3",20,10,32)
		MAGN E 0 A_FaceTarget
		MAGN E 5 bright A_SpawnItemEx ("riflechargeup3",20,10,32)
		MAGN E 4 A_FaceTarget
		TNT1 A 0 A_Jump (140, "missileshoot")
		goto chargefire
	missileshoot:
		MAGN E 12 A_PlaySound ("magegunner/missileload",0)
		MAGN E 15 A_PlaySound ("magegunner/attack",0)
		MAGN E 8 A_FaceTarget
		TNT1 A 0 A_Recoil (5)
		MAGN F 4 bright A_CustomMissile ("magicmissile")
		MAGN E 4
		goto see
	chargefire:
		MAGN E 15 A_PlaySound ("magegunner/attack",0)
		MAGN F 1 A_CustomMissile ("magebigshot")
		MAGN F 4 bright A_Recoil (5)
		MAGN E 4 
		goto see
	pain:
		MAGN G 4
		TNT1 A 0 A_TakeInventory ("PowerTerrorStatus",999)
		TNT1 A 0 A_TakeInventory ("PowerKickedStatus",999)
		MAGN G 8 A_Pain
		goto see
	Pain.Dazer:
    Pain.Superkick:
		MAGN G 4
		TNT1 A 0 A_GiveInventory ("KickDazer",1)
		MAGN G 8 A_Pain
		goto Dazed
    Dazed:
		MAGN G 2
		MAGN G 1 A_SetAngle (angle+15)
		MAGN G 1 A_JumpIfInventory ("PowerKickedStatus",1,"Dazed")
		Goto See
		
	death:
		TNT1 A 0 A_Jump (40, "specialdeath")
		MAGN G 1 A_Scream
		MAGN G 1 A_NoBlocking
		MAGN H 1 A_FaceTarget
		TNT1 A 0 thrustthingz (0,30,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 4, 0, 0)		
		MAGN H 3 
		MAGN I 3 
		MAGN J 2
		MAGN K 3
		MAGN L 2 A_PlaySound("magebane/fall",0)
		MAGN L -1 A_BossDeath
		stop
	xdeath:
		MAGN M 1 
		MAGN M 2 A_Fall
		MAGN M 0 A_PlaySound ("magegunner/xdeath",0)
		TNT1 A 0 A_SpawnItem ("bigdukebloodsplatter")
		TNT1 AAAAAAAA 0 A_SpawnItem ("dukebloodsplatter") 
		TNT1 AAA 0 A_SpawnItemEx("bonegib",0,0,0,random(-10,10),random(-10,10),10)		
		MAGN NOPQRSTU 4 
		MAGN U -1 A_BossDeath
		stop
	specialdeath:
		MAGN G 0 
		MAGN G 0 A_Stop
		MAGN G 1 A_Fall
		MAGN G 1 A_PlaySound ("magegunner/specialdeath",0)
		MAGN G 68 
		MAGN H 5 
		MAGN I 4
		MAGN J 4
		MAGN K 3
		MAGN L 2 A_PlaySound("magebane/fall",0)
		MAGN L -1 A_BossDeath
		stop		
	death.blazice:
		MAGN G 2 A_Scream
		MAIC A 2 A_NoBlocking
		TNT1 A 0 A_BossDeath
		TNT1 A 0 A_PlaySound ("swordtech/freezedeath")
		TNT1 A 0 A_FadeOut (0.20)
		TNT1 AAAAAAAAAAAA 0 A_SpawnItemEx ("iceparticle",random(-8,8),random(-8,8),32,random(-100,100)/10.0,random(-100,100)/10.0,random(-100,100)/20.0,0,160)
		MAIC B 90 bright
		MAIC C 2 bright
		TNT1 A 0 A_PlaySound ("swordtech/iceshatter")
		TNT1 AAAA 0 A_SpawnItemEx ("icefragment",0,0,0,random(-10,10),random(-10,10),10) 
		TNT1 AAAAAA 0 A_SpawnItemEx ("icefragment",0,0,0,random(-4,13),random(-8,13),8) 
		stop
	death.superkick:
		MAGN H 1 A_Scream
		MAGN H 1 a_scalevelocity (0.1)
		MAGN H 1 A_Stop
		MAGN H 1 A_NoBlocking
		TNT1 A 0 A_BossDeath
		TNT1 A 0 a_changeflag ("NOCLIP",1)
		TNT1 A 0 a_changeflag ("NOGRAVITY",1)
		MAGN H 1 A_FaceTarget
		TNT1 A 0 thrustthingz (0,80,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 110, 1, 0)
		TNT1 A 0 A_SpawnItemEx ("bosskickdeathsound")
        MAGN I 1
		MAGN J 2
	kickfly:
		MAGN JJJJJJJ 1 A_SpawnItemEx ("KustamParticle",random(-8,8),random(-8,8),random(-10,10),random(-120,120)/15.0,random(-130,130)/12.0,random(-110,110)/17.0,0)
		TNT1 A 0 A_FadeOut (0.02)
		loop
	death.Sentinelarm:
		MAGN G 1 A_Scream 
		MAGN G 1 A_NoBlocking 
		MAGN H 1 A_FaceTarget
		TNT1 A 0 thrustthingz (0,50,0,1)
		MAGN H 3 A_BossDeath
		MAGN I 3 
		MAGN J 2
		TNT1 A 0 a_nogravity
		TNT1 A 0 A_Stop
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",CHAN_VOICE,1,0,0.4)
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",5,1,0,0.6)
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",6,1,0,0.6)
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",7,1,0,0.6)
		OCKL ABCDEF 2 bright
		stop
		
	
	death.fatalslash:
		MAGN G 2 A_Scream
		MAIC A 4 A_NoBlocking
		TNT1 A 0 A_BossDeath
		MAGN G 15
	randomwait:
		FDMG A 1 A_Jump (20,"split")
		loop
	split:
		FDMG AABBCC 5
		FDMG DE 2
		FDMG FGHIJ 3 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
	exploding:
		FDMG J 1 Bright
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 Bright
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 Bright
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMG J 1 Bright A_Jump (100,"reallydie")
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		loop
	reallydie:
		TNT1 A 0
		TNT1 A 1 A_SpawnItemEx ("fataldrawdeath",0,0,30)
		stop
	Raise:
		MAGN LKJIHG 4 
		TNT1 A 0 A_Jump (40,"chaosexplode")
		goto see
	Chaosexplode:
 		TNT1 A 0
		TNT1 A 0 A_ChangeFlag("NOPAIN", 1)
		MAGN A 8
        MAGN G 6 A_Pain
    	MAGN A 8
        MAGN G 6 A_Pain
    	MAGN A 8
        MAGN G 6 A_Pain
        TNT1 A 0 A_Scream
		TNT1 A 0 A_BossDeath
        TNT1 A 0 A_NoBlocking
		TNT1 A 0 a_radiusgive ("chaoslaugh",650,RGF_MONSTERS)
		TNT1 A 0 A_SpawnItemEx("skellytun",0,0,12,random(-6,6),random(-8,8),random(6,10),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_PlaySound ("bonelord/explode",0,1,0,0.6)
		TNT1 A 0 Radius_Quake (4,20,0,32,0)
		TNT1 A 0 A_SpawnItem ("bigbloodsplatter")
		TNT1 AAAAAAAAAAAA 0 A_SpawnItem ("newbloodsplatter") 
		TNT1 AAAAAAAA 0 A_SpawnItemEx("bonegib",0,0,0,random(-30,30),random(-30,30),10)
		ISKL AAAAAAA 0 A_SpawnItemEx("hipbonegib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 A_SpawnItemEx("ribbonegib",0,0,32,random(-10,10),random(-10,10),12)
		TNT1 AAA 0 A_SpawnItemEx("bonegib",0,0,0,random(-30,30),random(-30,30),10)
		TNT1 A 20
		stop
	}
}


//Mage gunner projectiles

//Normal shot

actor magerifleshot 
{
	+notimefreeze
	projectile
	+THRUSPECIES
	species "enemyshot"
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	radius 6
	height 12
	speed 28
	damage (9)
	scale 1.5
	seesound "magegunner/rifle"
	states
	{
	spawn:
		MWND C 1 bright A_SpawnItem("magerifletrail")
		MWND D 1 bright A_SpawnItem("magerifletrail")
		loop
	Death:
		MWND E 4 Bright
		MWND F 3 Bright
		MWND G 4 Bright
		MWND H 3 Bright
		MWND I 4 Bright
		Stop
	}
}

//normal shot trails

ACTOR magerifletrail
{
	+NOBLOCKMAP
	+NOGRAVITY
	+SHADOW
	+NOTELEPORT
	+CANNOTPUSH
	+NODAMAGETHRUST
	+clientsideonly
	RenderStyle add
	Alpha 0.50
	scale 1.2
	States
	{
	Spawn:
		TNT1 A 0
		MWND CD 2 
		MWND CD 2
		Stop
	}
}

//Big shot

actor magebigshot
{
	+notimefreeze
	projectile
	+noblood
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	+SHOOTABLE
	+THRUSPECIES
	+DONTRIP
	-noblockmap
	species "enemyshot"
	health 99999
	mass 40
	radius 15
	height 12
	speed 20
	damage (20)
	scale 1.5
	seesound "magegunner/bigshot"
	states
	{
	spawn:
		MGCS E 2 bright
		MGCS F 2 bright A_SpawnItem ("bigshottrail")
		loop
	death:
		TNT1 A 0 A_CustomMissile("magerifleshot", 0,0, 0, CMF_AIMDIRECTION | CMF_TRACKOWNER)
		TNT1 A 0 A_CustomMissile("magerifleshot", 0,0, 80, CMF_AIMDIRECTION | CMF_TRACKOWNER)
		TNT1 A 0 A_CustomMissile("magerifleshot", 0,0, 160, CMF_AIMDIRECTION | CMF_TRACKOWNER)
		TNT1 A 0 A_CustomMissile("magerifleshot", 0,0, 240, CMF_AIMDIRECTION | CMF_TRACKOWNER)
		TNT1 A 0 A_CustomMissile("magerifleshot", 0,0, 320, CMF_AIMDIRECTION | CMF_TRACKOWNER)
 		MWND E 4 Bright
		MWND F 3 Bright
		MWND G 4 Bright
		MWND H 3 Bright
		MWND I 4 Bright
		Stop
	}
}

		
//big shot trails

actor bigshottrail 
{
	+NOGRAVITY
	+NOTELEPORT
	+CANNOTPUSH
	+clientsideonly
	+NODAMAGETHRUST
	scale 1.5
	states
	{
	spawn:
		TNT1 A 0
		TNT1 A 2
		MGCS CD 2 bright
		MGCS CD 2 bright
		MGCS AB 2 bright
		stop
	}
}


//Magic Missile

actor magicmissile
{
	+notimefreeze
	projectile
	species "enemyshot"
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
	+THRUGHOST
	radius 7
	height 12
	speed 20
	damage (30)
	scale 1.5
	seesound "magegunner/missileshot"
	deathsound "magegunner/missileexplode"
	states
	{
	spawn:
		MGMS A 2 bright A_SpawnItem ("missiletrail")
		loop
	death:
		TNT1 A 0 a_explode (40,120,0,0,80)
		TNT1 A 0 Radius_Quake (2,10,0,30,0)
		TNT1 AAAAAAA 0 a_spawndebris ("missiledebris1")
		TNT1 AAAAAAAAAAAA 0 A_SpawnItemEx ("missiledebris2",random(-16,16),random(-16,16),random(-10,10),random(-100,100)/20.0,random(-100,100)/20.0,random(-100,100)/20.0,0,160)
		MMXP ABCDEFGHIJKL 2
		stop
	}
}

actor missiletrail : bigshottrail
{
	states
	{
	spawn:
		TNT1 A 3
		MGSP AA 3 bright
		MGSP BB 2 bright
		MGSP C 2 bright
		stop
	death:
		TNT1 A 0
		stop
	}
}

actor missiledebris1
{
	Health 4
	radius 3
	height 6
	speed .1
	RenderStyle ADD
	scale 0.8
	Alpha	1
	Mass	0
	+missile
	+clientsideonly
	+doombounce
	+FLOORCLIP
	+DONTSPLASH
	+NOTELEPORT
	States
	{
		TNT1 A 0
		MGSP BBBBBB 1  Bright A_SetTranslucent(.6,1)
		MGSP BBBBBB 1 Bright 
		TNT1 BBB 1  Bright 
		MGSP BBBB 1 Bright 
		TNT1 BB 1  Bright 
		MGSP BB 1 Bright 
		TNT1 BB 1  Bright 
		MGSP B 1 Bright 
		TNT1 B 1  Bright 
		MGSP B 1 Bright 
		Stop
	}
}

actor missiledebris2
{
	projectile
	speed 10
	+clientsideonly
	+NOINTERACTION
	+NOTELEPORT
	states
	{
	spawn:	
		TNT1 A 0
		MGSP BBBBBB 1  Bright A_SetTranslucent(.6,1)
		TNT1 BB 1  Bright 
		MGSP BB 1 Bright 
		TNT1 BB 1  Bright 
		MGSP B 1 Bright 
		TNT1 B 1  Bright 
		MGSP B 1 Bright 
		Stop
	}
}
	
//Charge up effects

actor riflechargeup1
{
	+NOBLOCKMAP
	+clientsideonly
	+NOINTERACTION
	+NOTELEPORT
	+CANNOTPUSH
	+NODAMAGETHRUST
	+bright
	states
	{
	spawn:
		TNT1 A 0
		MGCS ABABAB 4
		stop
	death:
		TNT1 A 0
		stop
	}
}

actor riflechargeup2 : riflechargeup1
{
	states
	{
	spawn:
		MGCS CDCDCD 4
		stop
	}
}

actor riflechargeup3 : riflechargeup1
{
	states
	{
	spawn:
		MGCS EFEFEF 3
		stop
	}
}

		