ACTOR Hellfos : baronofhell replaces baronofhell
{ 
	Health 1000
	Radius 24
	Height 63
	Mass 1000 
	Speed 13
	PainChance 60 
 	Painchance "BarrelGrab", 0
	MONSTER
	+DONTHARMSPECIES
	+FLOORCLIP 
	+MISSILEMORE
	+BOSSDEATH
	+noblooddecals
    bloodtype RevBoneSpray
	MeleeRange 80
	Obituary "%o was crushed by a Hellfos."
	HitObituary "A Hellfos bested %o in a swordfight" 
	SeeSound "hellfos/see" 
	PainSound "hellfos/pain" 
	DeathSound "hellfos/die" 
	ActiveSound "hellfos/active" 
	dropitem "lilchest" 60
	States 
	{ 
	Spawn: 
		DKNT AB 10 A_Look 
		Loop 
	See:
		DKNT AAA 2 A_Chase
		DKNT BBB 2 A_Chase
		TNT1 A 0 A_PlaySound ("hellfos/step", 7, 1, 0, 1.5)
		DKNT CCC 2 A_Chase
		DKNT DDD 2 A_Chase
		TNT1 A 0 A_PlaySound ("hellfos/step", 7, 1, 0, 1.5)
		Loop
	Melee:
		DKNT E 6 A_FaceTarget
		DKNT F 1 A_PlaySound ("hellfos/melee",CHAN_BODY)
		DKNT F 4 A_FaceTarget
		DKNT G 7 A_CustomMeleeAttack (25, "mace/hit",0)
		Goto See
	Missile:
		TNT1 A 0
		TNT1 A 0 A_JumpIfCloser (500, "midrangechoices")
	swordbeam:    
		DKNT E 10 Bright A_FaceTarget
		DKNT F 6 Bright A_PlaySound ("monster/kntswg",CHAN_BODY)
		DKNT G 0 Bright A_CustomMissile ("HellfosBeam",32,0,-4,0)
		DKNT G 0 Bright A_CustomMissile ("HellfosBeam",32,0,0,0)
		DKNT G 5 Bright A_CustomMissile ("HellfosBeam",32,0,4,0)
		Goto See
	midrangechoices:
		TNT1 A 0
		DKNT A 1 A_Jump (60,"rapidshot")
		goto swordbeam
	rapidshot:
		DKNT T 10 Bright A_FaceTarget      
		DKNT U 3 Bright A_CustomMissile ("quickdagger",44,0,random(-4,11),2,random(-2,4))
		TNT1 AAAAA 0 A_CustomMissile ("quickdagger",44,0,random(-4,11),2,random(-2,4))
		DKNT T 4 Bright A_FaceTarget      
		DKNT U 4 Bright A_CustomMissile ("quickdagger",44,0,random(-4,11),2,random(-2,4))
		TNT1 AAAAA 0 A_CustomMissile ("quickdagger",44,0,random(-4,11),2,random(-2,4))
		DKNT T 4 Bright A_FaceTarget      
		DKNT U 4 Bright A_CustomMissile ("quickdagger",44,0,random(-4,11),2,random(-2,4))
		TNT1 AAAAA 0 A_CustomMissile ("quickdagger",44,0,random(-4,11),2,random(-2,4))
		goto see

	Pain:
		TNT1 A 0 A_GiveInventory ("rage", 1)
		DKNT H 2 
		TNT1 A 0 A_TakeInventory ("PowerTerrorStatus",999)
		TNT1 A 0 A_TakeInventory ("PowerKickedStatus",999)
		TNT1 A 0 A_PlaySound ("skeleton/allpain",0,1,0,0.5)
		DKNT H 2 A_Pain
		TNT1 A 0 A_Jumpifinventory ("rage", 3, "evasion")
		DKNT H 1
		Goto See
	Pain.Dazer:
	Pain.Superkick:
		DKNT H 2 
		TNT1 A 0 A_PlaySound ("skeleton/allpain",0,1,0,0.5)
		TNT1 A 0 A_GiveInventory ("KickDazer",1)
		DKNT H 2 A_Pain
		DKNT H 1
		Goto Dazed
    Dazed:
		DKNT H 2
		DKNT H 1 A_SetAngle (angle+15)
		DKNT H 1 A_JumpIfInventory ("PowerKickedStatus",1,"Dazed")
		Goto See
	evasion:	
		TNT1 A 0 A_TakeInventory ("rage", 99)
		TNT1 A 0 A_Jump (100, "jumpright")
		TNT1 A 0 A_Jump (100, "jumpback")
		TNT1 A 0 ThrustThingZ (0,10,0,1)
		TNT1 A 0 ThrustThing (angle*256/360+192, 10, 0, 0)
		DKNT U 5
		goto see
	jumpback:
		TNT1 A 0 A_TakeInventory ("rage", 99)
		DKNT E 8 A_FaceTarget
		TNT1 A 0 ThrustThingZ(0,10,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 10, 0, 0)
		DKNT F 1 A_PlaySound ("hellfos/melee")
		DKNT F 4 A_FaceTarget
		DKNT G 4 A_CustomMeleeAttack (15, "mace/hit",0)
		DKNT G 4
		TNT1 A 0 A_Jump (30, "missile")
		goto see   
	jumpright:
		TNT1 A 0 A_TakeInventory ("rage", 99)
		TNT1 A 0 ThrustThingZ(0,10,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+64, 10, 0, 0)
		DKNT U 5
		goto see


	Death:
		DKNT I 1 Bright A_Scream
		DKNT I 1 Bright A_NoBlocking
		DKNT I 1 Bright A_FaceTarget
		TNT1 A 0 ThrustThingZ (0,30,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 4, 0, 0)		
		TNT1 A 0 A_SpawnItemEx("HellfosSword", 0, 0, 44, random(-10,10), 0, 10, -90, 128)
		TNT1 A 0 A_SpawnItemEx("HellfosShield", 0, 0, 44, random(-10,10), 0, 10, -90, 128)
		DKNT I 1 Bright 
		DKNT J 4 Bright 
		DKNT K 3 Bright
		DKNT L 2 Bright 
		TNT1 A 0 A_PlaySound ("hellfos/fall",CHAN_BODY)
		DKNT MN 3 Bright 
		DKNT O -1 A_BossDeath
		Stop 
	XDeath:
		DKNT I 0 Bright A_Scream
		DKNT I 0 Bright A_NoBlocking
		DKNT I 0 Bright A_FaceTarget
		TNT1 A 0 ThrustThingZ (0,30,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 6, 0, 0)		
		TNT1 A 0 A_SpawnItemEx("HellfosSword", 0, 0, 44, random(-10,10), 0, 10, -90, 128)
		TNT1 A 0 A_SpawnItemEx("HellfosShield", 0, 0, 44, random(-10,10), 0, 10, -90, 128)
		TNT1 A 0 A_PlaySound ("skeleton/gib",0,1,0,0.6)
		TNT1 AAAAAA 0 A_SpawnItemEx("RevBoneGib",0,0,0,random(-10,10),random(-10,10),random(11,15))
		TNT1 AAAAAA 0 A_SpawnItemEx("RevBoneGib",0,0,0,random(-14,18),random(-15,19),random(11,15))
		TNT1 AAAAAA 0 A_SpawnItemEx("RevBoneGib",0,0,0,random(-8,15),random(-20,13),random(11,15))
		ISKL AAAAAAA 0 A_SpawnItemEx("RevHipBoneGib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 A_SpawnItemEx("RevRibBoneGib",0,0,32,random(-10,10),random(-10,10),12)
		DKNT J 2 Bright 
		DKNT K 1 Bright
		DKNT L 2 Bright 
		TNT1 A 0 A_PlaySound ("hellfos/fall",CHAN_BODY)
		DKNT MN 3 Bright 
		DKNT O -1 A_BossDeath
		Stop 
	
	Death.superkick:	
		DKNT I 1 A_Scream 
		DKNT I 1 A_ScaleVelocity (0.1)
 		DKNT I 1 A_Stop
		DKNT I 1 A_NoBlocking
		TNT1 A 0 A_BossDeath
		TNT1 A 0 A_ChangeFlag ("NOCLIP",1)
		TNT1 A 0 A_ChangeFlag ("NOGRAVITY",1)
		DKNT I 1 A_FaceTarget
		TNT1 A 0 ThrustThingZ (0,80,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 110, 1, 0)
		TNT1 A 0 A_SpawnItemEx("HellfosSword", 30, 0, 44, 0, 0, 4, -90, 128)
		TNT1 A 0 A_SpawnItemEx("HellfosShield", -30, 0, 44, 0, 0, 4, -90, 128)
		TNT1 A 0 A_SpawnItemEx ("bosskickdeathsound")
		DKNT J 1
		DKNT K 2		
	kickfly:
		DKNT LLLLLLL 1 A_SpawnItemEx ("KustamParticle",random(-8,8),random(-8,8),random(-10,10),random(-120,120)/15.0,random(-130,130)/12.0,random(-110,110)/17.0,0)
		TNT1 A 0 A_FadeOut (0.02)
		loop	
	Death.Sentinelarm:
		DKNT I 1 Bright A_Scream
		DKNT I 1 Bright A_NoBlocking
		DKNT I 1 Bright A_FaceTarget
		TNT1 A 0 ThrustThingZ (0,40,0,1)
		TNT1 A 0 A_SpawnItemEx("HellfosSword", 0, 0, 44, random(-10,10), 0, 10, -90, 128)
		TNT1 A 0 A_SpawnItemEx("HellfosShield", 0, 0, 44, random(-10,10), 0, 10, -90, 128)
		DKNT I 1 Bright 
		DKNT J 4 Bright 
		DKNT K 3 Bright
		DKNT L 2 Bright 
		DKNT M 3 Bright 
		TNT1 A 0 A_BossDeath
		TNT1 A 0 A_NoGravity
		TNT1 A 0 A_Stop
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",CHAN_VOICE,1,0,0.4)
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",5,1,0,0.6)
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",6,1,0,0.6)
		TNT1 A 0 A_PlaySound ("Kustam/OCKill",7,1,0,0.6)
		OCKL ABCDEF 2 bright
		Stop 

	Raise: 
		DKNT ONMLKJI 4 Bright
		TNT1 A 0 A_Jump (40, "chaosexplode")
		Goto See 
	death.blazice:
		TNT1 A 0
		TNT1 A 0 A_BossDeath
		DKNT H 2 A_Scream
		DKIC A 2 A_NoBlocking
		TNT1 A 0 A_PlaySound ("swordtech/freezedeath",CHAN_BODY)
		TNT1 A 0 A_FadeOut (0.20)
		TNT1 AAAAAAAAAAAA 0 A_SpawnItemEx ("iceparticle",random(-8,8),random(-8,8),32,random(-100,100)/10.0,random(-100,100)/10.0,random(-100,100)/20.0,0,160)
		DKIC B 90 bright
		DKIC C 2 bright
		TNT1 A 0 A_PlaySound ("swordtech/iceshatter",CHAN_BODY)
		TNT1 AAA 0 A_SpawnItemEx ("icefragment",0,0,0,random(-10,10),random(-10,10),10) 
		TNT1 AAAA 0 A_SpawnItemEx ("icefragment",0,0,0,random(-4,13),random(-8,13),8) 
		stop
 	death.fatalslash:
		DKNT H 2 A_Scream
		DKIC A 4 A_NoBlocking
		TNT1 A 0 A_BossDeath
		DKNT H 15
	randomwait:
		FDHF A 1 A_Jump (20,"split")
		loop
	split:
		FDHF AABBCC 5
		FDHF DE 2
		FDHF FGHIJ 3 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
	exploding:
		FDHF J 1 Bright
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 Bright
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 Bright
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDHF J 1 Bright A_Jump (100,"reallydie")
		TNT1 A 1 Bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,30), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		loop
	reallydie:	
		TNT1 A 0 
		TNT1 A 1 A_SpawnItemEx ("fataldrawdeath",0,0,30)
		stop
	Chaosexplode:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag("NOPAIN", 1)
    	DKNT A 8
        DKNT H 6 A_Pain
    	DKNT A 8
        DKNT H 6 A_Pain
    	DKNT A 8
        DKNT H 6 A_Pain
		TNT1 A 0 A_Scream
		TNT1 A 0 A_BossDeath
		TNT1 A 0 a_radiusgive ("chaoslaugh",650,RGF_MONSTERS)
		TNT1 A 0 A_SpawnItemEx("skellytun",0,0,12,random(-6,6),random(-8,8),random(6,10),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 A_PlaySound ("bonelord/explode",CHAN_BODY,1,0,0.6)
		TNT1 A 0 Radius_Quake (4,20,0,32,0)
		TNT1 AAAAAAAAAAAAA 0 A_SpawnItemEx ("SkellytunSkullDeath",random(-16,16),random(-16,16),42,random(-100,100)/20.0,random(-100,100)/20.0,random(-100,100)/20.0,0)
		TNT1 AAAAAAAAA 0 A_SpawnItemEx("RevBoneGib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		TNT1 AAAAAA 0 A_SpawnItemEx("RevBoneGib",0,0,32,random(-10,10),random(-10,10),random(5,10))
		ISKL AAAAAAA 0 A_SpawnItemEx("RevHipBoneGib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 A_SpawnItemEx("RevRibBoneGib",0,0,32,random(-10,10),random(-10,10),12)
		TNT1 A 20
		stop

	} 
}

ACTOR HellfosBeam
{
	Radius 7
	Height 12
	Speed 20
	Damage (15)
	RENDERSTYLE translucent 
	ALPHA 0.90
	PROJECTILE
	+THRUSPECIES
	species "enemyshot"
	Seesound "monster/dkndrt"
	DeathSound "weapons/firex2"
	States
	{
	Spawn:
		FHED ABCD 2 Bright
		loop
	Death:
		TNT1 A 0
		DKAT D 0 Bright A_SetTranslucent (0.85,1)
		TNT1 A 0
		DKAT D 0 Bright A_SetTranslucent (0.85,1)
		DKAT D 3 Bright
		DKAT E 3 Bright
		DKAT FG 3 Bright
		DKAT IJKLM 3 Bright
		stop
	}
}

actor quickdagger
{
	+notimefreeze
	+bloodsplatter
	+forcexybillboard
	+THRUSPECIES
	Radius 5
	Height 8
	species "enemyshot"
	projectile
	-nogravity
	gravity 0.2
	damage (3)
	scale 0.5
	speed 25
	seesound "cannon/turretattack"
	states
	{
	spawn:
		DGGR A 1 ThrustThingZ (0, random(15,60),0,0)
	flying:
		DGGR A 1 bright
		TNT1 A 0 a_spawnitem ("quicktrail")
		loop
	death:
		TNT1 A 0
		stop
	xdeath:
		TNT1 A 0 A_PlaySound ("gauntlet/darthit",CHAN_BODY)
		NLPJ BCDEDFG 3 
		stop				
	}
}

actor quicktrail
{
	alpha 0.60
	projectile
	+noclip
	+dontblast
	+clientsideonly
	+NOTELEPORT
	scale 0.5
	states
	{
	spawn:
		TNT1 A 0
		DGGR A 1 bright A_FadeOut (0.08)
		loop
	}
}


ACTOR HellfosSword
{   
	Radius 8
	Height 8
	Speed 1
	PROJECTILE
	RENDERSTYLE Normal
	+clientsideonly
	-NOGRAVITY
	+NOTELEPORT
	States
	{
	Spawn:
		TNT1 A 0
		SWRD KLMNOPQ 3 BRIGHT
		goto Death 
	Death:
		SWRD RS 4 BRIGHT
		SWRD T 4 BRIGHT
		SWRD U 4
		SWRD T 4 BRIGHT
		SWRD U 8
		SWRD T 4 BRIGHT
		SWRD U 16
		SWRD T 4 BRIGHT
		SWRD U -1
	}
}

ACTOR HellfosShield
{   
	Radius 8
	Height 8
	Speed 1
	+clientsideonly
	PROJECTILE
	RENDERSTYLE Normal
	-NOGRAVITY
	+NOTELEPORT
	States
	{
	Spawn:
		TNT1 A 0
		SHLD ABCDEFGHI 3
		goto death 
	Death:
		SHLD H -1
	}
}

actor rage : inventory
{inventory.maxamount 5}