actor magebane : actor replaces spectre 
{
	Health 100 
	PainChance 180 
	Speed 10
	Radius 30 
	Height 56 
	Mass 400 
	MONSTER
	meleerange 60
  	Painchance "BarrelGrab", 0
    bloodtype newbloodsplatter
	seesound "magebane/spot"
	painsound "magebane/hurt"
	deathsound "magebane/die"
	+floorclip
    Obituary "%o didn't duck the thief's knife."
    HitObituary "%o had their life robbed by a thief."
	dropitem "lilchest" 10
	states
	{
	spawn:
		DATF AB 10 a_look
		loop
	see:
		DATF AABBCCDD 2 a_chase
		loop
	melee:
		DATF E 8 a_facetarget
		TNT1 A 0 a_jump (100, "grunt")
		DATF F 10 a_custommeleeattack(15,"magebane/stab","magebane/knife","thiefknife")
		DATF F 5
		goto see
	grunt:
		TNT1 A 0 a_playsound ("magebane/attack", 0)
		DATF F 10 a_custommeleeattack(15,"magebane/stab","magebane/knife","thiefknife")
		DATF F 5		
		goto see
	/* missile:
		DATF E 2 a_facetarget
		DATF E 4 a_playsound ("magebane/windup",0)
		DATF E 2 a_facetarget
		DATF F 9 a_custommissile ("magebaneknife")
		DATF F 5
		goto see */
	pain:
		DATF G 4 
 		TNT1 A 0 A_TakeInventory ("PowerTerrorStatus",999)
		TNT1 A 0 a_takeinventory ("PowerKickedStatus",999)
		DATF G 8 a_pain
		goto see
	Pain.Dazer:
    Pain.Superkick:
		DATF G 4 
		TNT1 A 0 a_giveinventory ("KickDazer",1)
		DATF G 8 a_pain
		goto Dazed
    Dazed:
		DATF G 2
		DATF G 1 A_SetAngle (angle+15)
		DATF G 1 A_JumpIfInventory ("PowerKickedStatus",1,"Dazed")
		Goto See
		
	death:
		DATF H 2 a_scream
		TNT1 A 0 a_spawnitemex ("droppedknife", 0, 0, 10,random(1,3),random(1,4),5)
		DATF HIJK 5 a_noblocking
		DATF L 2 a_playsound ("gibs/bodyhitfloor",0)
		DATF M 2 
		DATF N -1
		stop
	death.superkick:
		DATF H 1 a_scream
		DATF H 1 a_scalevelocity (0.1)
		DATF H 1 a_stop
		DATF H 1 a_noblocking
		TNT1 A 0 a_changeflag ("NOCLIP",1)
		TNT1 A 0 a_changeflag ("NOGRAVITY",1)
		DATF H 1 a_facetarget
		TNT1 A 0 a_spawnitemex ("droppedknife", 0, 0, 10,1,0,1)
		TNT1 A 0 thrustthingz (0,80,0,1)
		TNT1 A 0 ThrustThing(angle*256/360+128, 110, 1, 0)
		TNT1 A 0 a_spawnitemex ("kickdeathsound")
		DATF I 1
	kickfly:
		DATF IIIIIII 1 a_spawnitemex ("KustamParticle",random(-8,8),random(-8,8),random(-10,10),random(-120,120)/15.0,random(-130,130)/12.0,random(-110,110)/17.0,0)
		TNT1 A 0 a_fadeout (0.02)
		loop
	death.SentinelArm:
		DATF H 2 a_scream
		TNT1 A 0 a_spawnitemex ("droppedknife", 0, 0, 10,random(1,3),random(1,4),5)
		DATF H 2 a_noblocking
		TNT1 A 0 thrustthingz (0,50,0,1)
		DATF H 8
		TNT1 A 0 a_nogravity
		TNT1 A 0 a_stop
		TNT1 A 0 a_playsound ("Kustam/OCKill",CHAN_VOICE,1,0,0.4)
		TNT1 A 0 a_playsound ("Kustam/OCKill",5,1,0,0.6)
		TNT1 A 0 a_playsound ("Kustam/OCKill",6,1,0,0.6)
		TNT1 A 0 a_playsound ("Kustam/OCKill",7,1,0,0.6)
		OCKL ABCDEF 2 bright
		stop
	death.blazice:
		DATF G 2 a_scream
		DAIC A 2 A_noblocking
		TNT1 A 0 a_playsound ("swordtech/freezedeath")
		TNT1 A 0 a_fadeout (0.20)
		TNT1 AAAAAAAAAAAA 0 a_spawnitemex ("iceparticle",random(-8,8),random(-8,8),32,random(-100,100)/10.0,random(-100,100)/10.0,random(-100,100)/20.0,0,160)
		DAIC B 90 bright
		DAIC C 2 bright
		TNT1 A 0 a_playsound ("swordtech/iceshatter")
		TNT1 AAA 0 a_spawnitemex ("icefragment",0,0,0,random(-10,10),random(-10,10),10) 
		TNT1 AAAA 0 a_spawnitemex ("icefragment",0,0,0,random(-4,13),random(-8,13),8) 
		stop
	death.fatalslash:
		DATF G 2 a_scream
		DAIC A 4 a_noblocking
		DATF G 15
	randomwait:
		FDMB A 1 a_jump (20,"split")
		loop
	split:
		FDMB AABBCC 5
		FDMB DE 2
		FDMB FGHIJ 3 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
	exploding:
		FDMB J 1 bright 
		TNT1 A 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright 
		TNT1 A 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright 
		TNT1 A 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		FDMB J 1 bright a_jump (100,"reallydie")
		TNT1 A 1 bright A_SpawnItemEx ("fatalburst", frandom(-20,20),frandom(-20,20),frandom(10,35), 0,0,0, 0, SXF_NOCHECKPOSITION,80)
		loop
	reallydie:
		TNT1 A 0
		TNT1 A 1 a_spawnitemex ("fataldrawdeath",0,0,30)
		stop
	raise:
		DATF NMLKJIH 5
		TNT1 A 0 a_jump (60,"chaosexplode")
		goto see
	xdeath:
		DATF H 1 a_scream
		TNT1 A 0 a_spawnitemex ("droppedknife", 0, 0, 20,random(4,6),random(2,8),10)		
		TNT1 A 0 a_spawnitem ("bigbloodsplatter")
		TNT1 AAAAAAAA 0 a_spawnitemex ("newbloodsplatter",0,0,24)       		
		//TNT1 AAAAAAAA 0 a_spawnitem ("newbloodsplatter")       
		TNT1 AAAAAAAA 0 a_spawnitemex("bonegib",0,0,0,random(-10,10),random(-10,10),16)
		TNT1 AAA 0 a_spawnitemex("bonegib",0,0,0,random(-10,10),random(-10,10),10)
		ISKL AAAA 0 a_spawnitemex("hipbonegib",0,0,0,random(-10,10),random(-10,10),10)
		ISKL A 0 a_spawnitemex("ribbonegib",0,0,0,random(-10,10),random(-10,10),12)
		stop
    ChaosExplode:
		TNT1 A 0
		TNT1 A 0 A_ChangeFlag("NOPAIN", 1)
		DATF A 8
        DATF G 6 A_Pain
    	DATF A 8
        DATF G 6 A_Pain
    	DATF A 8
        DATF G 6 A_Pain
        TNT1 A 0 a_scream
        TNT1 A 0 A_NoBlocking
		TNT1 A 0 a_radiusgive ("chaoslaugh",650,RGF_MONSTERS)
		TNT1 A 0 a_spawnitemex("skellytun",0,0,12,random(-6,6),random(-8,8),random(6,10),0,SXF_NOCHECKPOSITION)
		TNT1 A 0 a_playsound ("bonelord/explode",0,1,0,0.6)
		TNT1 A 0 Radius_Quake (4,20,0,32,0)
		TNT1 A 0 a_spawnitem ("bigbloodsplatter")
		TNT1 AAAAAAAAAAAA 0 a_spawnitem ("newbloodsplatter") 
		TNT1 AAAAAAAA 0 a_spawnitemex("bonegib",0,0,0,random(-30,30),random(-30,30),10)
		ISKL AAAAAAA 0 a_spawnitemex("hipbonegib",0,0,32,random(-10,10),random(-10,10),10)
		ISKL AAAAA 0 a_spawnitemex("ribbonegib",0,0,32,random(-10,10),random(-10,10),12)
		TNT1 AAA 0 a_spawnitemex("bonegib",0,0,0,random(-30,30),random(-30,30),10)
		TNT1 A 20
		stop
	}
}

actor magebaneknife
{
	+notimefreeze
	+bloodsplatter
	+forcexybillboard
	+THRUSPECIES
	+THRUGHOST
	species "enemyshot"
	projectile
	damage (8)
	speed 25
	seesound "cannon/turretattack"
	damagetype thrownthiefknife
	states
	{
	spawn:
		DGGR A 1 bright
		loop
	crash:
		TNT1 A 0 a_playsound ("subweapons/miss")
		SWMS ABC 3 bright
		stop
	death:
		TNT1 A 0 a_playsound ("subweapons/miss")
		SWMS ABC 3 bright
		stop
	xdeath:
		TNT1 A 0 a_playsound ("implord/javelinhit")
		SWHT ABC 3 bright
		stop
	}
}


actor droppedknife 
{
	+notimefreeze
	+cannotpush
	+movewithsector
	+dontsplash
	+noblockmap
	+missile
	bouncetype doom
	+thruactors
	-nogravity
	+FORCEXYBILLBOARD	
	+LOOKALLAROUND
 	+clientsideonly
	+bounceonactors
	+NOTELEPORT
	scale 1.2
	states
	{
	spawn:
		TNT1 A 0
		TFKF ABCD 3 
	FallingLoop:
		TFKF ABCD 3 
		TFKF A 1 A_JumpIf(Abs(VelZ) <= 0.01, "Death")
		loop
	death:
		TFKF E -1
		stop
	}
}